Plush Controller with EagLED

#include <Keyboard.h>
#include <CapPin.h>

CapPin cPin_0 = CapPin(0);    // read pin 0 (RX#0 on EagLED) - connect to Down arrow
CapPin cPin_1  = CapPin(1);     // read pin 1 (TX#1 on EagLED)   - connect to Right arrow
CapPin cPin_2  = CapPin(2);     // read pin 2 (SDA#2 on EagLED)   - connect to Left arrow
CapPin cPin_3 = CapPin(3);    // read pin 3 (SCL#3 on EagLED) - connect to Up arrow
CapPin cPin_6  = CapPin(6);     // read pin 6 (#6 on EagLED)   - connect to 'A' button
CapPin cPin_9  = CapPin(9);     // read pin 9 (#A9 on EagLED)   - connect to 'X' button
CapPin cPin_10  = CapPin(10);     // read pin 10 (#10 on EagLED)  - connect to 'Y' button
CapPin cPin_12 = CapPin(12);     // read pin 12 (#12 on EagLED)  - connect to 'B' button

CapPin pins[] = {cPin_0, cPin_1, cPin_2, cPin_3, cPin_6, cPin_9, cPin_10, cPin_12};

char Keys[] = { KEY_DOWN_ARROW, KEY_RIGHT_ARROW, KEY_LEFT_ARROW, KEY_UP_ARROW, 'a', 'x' , 'y' , 'b'};

boolean currentState[] = {false, false, false, false, false, false, false, false};

#define THRESHOLD 1000

void setup() {
  Keyboard.begin();
}

void loop() {

  for (int i = 0; i < 8; i++) {
    delay(1);
    long total =  pins[i].readPin(2000);

    // check if a finger is touching the pad and it was not already pressed
    if ((total > THRESHOLD) && (! currentState[i])) {
      currentState[i] = true;

      Keyboard.press(Keys[i]);
    }
    else if ((total <= THRESHOLD) && (currentState[i])) {
      currentState[i] = false;

      Keyboard.release(Keys[i]);
    }

    delay(5);
  }

}